1. CDS – ZFIND_CDS

@AbapCatalog.sqlViewName: 'ZCDS_FINDER'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Find CDS view for Table'
define view ZFIND_CDS
  as select from dd25t as _dd25t
  association [0..*] to ddldependency as _ddldependency
    on _dd25t.viewname = _ddldependency.objectname
  association [0..*] to dd26s         as _dd26s
    on _dd25t.viewname = _dd26s.viewname
  association [0..*] to tadir         as _tadir
    on _dd25t.viewname = _tadir.obj_name
{

  key _ddldependency.ddlname[inner] as CdsViewName,
  key _dd25t.viewname               as SqlViewname,

      _dd26s.tabname                as BaseTableName,

      _dd25t.ddtext                 as CdsText,

      case _tadir.author
        when 'SAP'
            then 'Standard'
      else
        'Custom'
      end                           as ObjectIdentifier,

      _tadir.devclass               as PackageUsed,
      _tadir.author                 as CreatedBy,
      _tadir.created_on             as CreatedOn,

      _dd25t.as4local               as ActivationState,
      _dd25t.as4vers                as Version,

      _dd25t.ddlanguage[inner]      as OriginalLanguage,

      _ddldependency.objecttype     as Objecttype,

      _dd26s.viewname[inner]        as Viewname,

      _dd26s.tabpos                 as RepetitionGroupPosition,
      _dd26s.fortabname             as BaseTableForeignKeyRel,
      _dd26s.forfield               as JoinRelForeignKeyField,
      _dd26s.fordir                 as DirectionOfForeignKeyDep

}

Output :